<?xml version="1.0" encoding="utf-8"?>
<mx:Box xmlns:mx="http://www.adobe.com/2006/mxml"
	direction="vertical"
	xmlns:flexlib="flexlib.scheduling.*"
	creationComplete="onCreationComplete()"
	>
	
	<mx:Metadata>
        [Event(name="selectTripItem", type="tripvisUI.events.TimelineEvent")]
    </mx:Metadata>
	
	<mx:Script>
		<![CDATA[
			import flash.utils.getDefinitionByName;
			import tripvisUI.languages.LanguageDirector;
			import tripvisModel.controllers.BasketControllerEvent;
			import tripvisModel.controllers.BasketController;
			import tripvisModel.controllers.TimelineControllerEvent;
			import tripvisModel.TripVisModel;
			import tripvisModel.controllers.TimelineController;
			import tripvisUI.flexlibextention.TripScheduleEntryRenderer;
			import mx.core.UIComponent;
			import mx.managers.DragManager;
			import mx.events.DragEvent;
			import tripvisUI.events.TimelineEvent;
			import tripvisUI.flexlibextention.EntryEvent;
			import mx.events.CollectionEvent;
			import tripvisModel.TripItemType;
			import tripvisModel.TripItem;
			import tripvisUI.flexlibextention.TripScheduleEntry;
			
			import flexlib.scheduling.samples.ScheduleData;
			import flexlib.scheduling.scheduleClasses.ColoredScheduleEntry;
			import flexlib.scheduling.scheduleClasses.BackgroundItem;
			import flexlib.scheduling.scheduleClasses.LayoutScrollEvent;
			import flexlib.scheduling.util.DateUtil;
			
			import mx.collections.IList;
			import mx.collections.ArrayCollection;
			import mx.controls.Alert;
			import mx.events.ScrollEvent;
			import mx.events.ScrollEventDirection;
			
			[Bindable]
			private var dataProvider : IList;
			[Bindable]
			private var rowDataProvider : IList;
			[Bindable]
			private var startDate : Date;
			[Bindable]
			private var endDate : Date;
			[Bindable]
			private var zoom : Number;
			[Bindable]
			public var scheduleViewerWidth : Number = 854 /* - 256 */;
			[Bindable]
			private var scheduleViewerHeight : Number;
			[Bindable]
			private var timebarHeight : Number = 56;
			
			private var _visitsRow: ArrayCollection = new ArrayCollection; // bevat TripScheduleEntries
			private var _hotelsRow: ArrayCollection = new ArrayCollection; // bevat TripScheduelEntries
			
			private var _timelineController: TimelineController;
				   
			private function onCreationComplete() : void
			{
				_timelineController = TripVisModel.instance.timelineController;
				
				scheduleViewerHeight = timebarHeight * 2;
				
				startDate = _timelineController.timelineStartDate;
				endDate = _timelineController.timelineEndDate;
				
				// set dataprovider
				var entries : ArrayCollection = new ArrayCollection();
				entries.addItem( this._visitsRow );
				entries.addItem( this._hotelsRow );
				
				dataProvider = entries;
				
				// timeline labels:
				rowDataProvider = new ArrayCollection();
				//rowDataProvider = [];
				rowDataProvider.addItem( { label: LanguageDirector.instance.language.timebarVisits } ); 
				rowDataProvider.addItem( { label: LanguageDirector.instance.language.timebarHotels } ); 
				
				zoom = 500;
								
				
				_timelineController.addEventListener(TimelineControllerEvent.TRIP_ITEM_ADDED, timelineController_tripItemAdded);
				_timelineController.addEventListener(TimelineControllerEvent.TRIP_ITEM_REMOVED, timelineController_tripItemRemoved);
				_timelineController.addEventListener(TimelineControllerEvent.TRIP_ITEMS_CLEARED, timelineController_tripItemsCleared);
			
				var basketController: BasketController = TripVisModel.instance.basketController;
				basketController.addEventListener(BasketControllerEvent.TRIP_ITEM_UPDATED, basketController_tripItemUpdated);
			}
			
			private function timelineController_tripItemAdded(event: TimelineControllerEvent): void
			{
				trace(event.target.toString());
				
				var addedTripItem: TripItem = event.tripItem;
				
				switch(addedTripItem.type)
				{
					case TripItemType.LANDMARK:
						addLandmarkRestaurant(addedTripItem);
						break;
					case TripItemType.EATINGPLACE:
						addLandmarkRestaurant(addedTripItem);
						break;
					case TripItemType.HOTEL:
						addHotel(addedTripItem);
						break;
					default:
						addLandmarkRestaurant(addedTripItem);
						break;
				}
				
				this.updateTimeline();
			}
			
			private function addLandmarkRestaurant(tripItem: TripItem): void
			{
				var lastDate: Date = new Date(_timelineController.timelineStartDate);
				
				if (_visitsRow.length == 0)
				{
					if (_hotelsRow.length > 0)
					{
						lastDate.setTime((_hotelsRow[0] as TripScheduleEntry).tripItem.timePeriod.startDate.getTime());
					}
				}
				else
				{
					for each(var tripScheduleEntry: TripScheduleEntry in _visitsRow)
					{
						var tripItem2: TripItem = tripScheduleEntry.tripItem;
						if (tripItem2.timePeriod.endDate.getTime() > lastDate.getTime())
							lastDate.setTime(tripItem2.timePeriod.endDate.getTime());
					}
					
					lastDate.minutes++;
				}
				
				var newStartDate: Date = new Date(lastDate);
				var newEndDate: Date = new Date(lastDate.getTime() + tripItem.timePeriod.getDuration());
				
				_timelineController.updateTripItemStartDate(tripItem, newStartDate);
				_timelineController.updateTripItemEndDate(tripItem, newEndDate);
				
				_visitsRow.addItem(new TripScheduleEntry(tripItem));
			}
			
			private function addHotel(tripItem: TripItem): void
			{
				var hotelStartDate: Date = new Date(_timelineController.timelineStartDate);
				
				if (_hotelsRow.length > 0)
				{
					// laatste hotel zoeken
					for each(var tripScheduleEntry: TripScheduleEntry in _hotelsRow)
					{
						var tripItem2: TripItem = tripScheduleEntry.tripItem;
						if (tripItem2.timePeriod.endDate.getTime() > hotelStartDate.getTime())
							hotelStartDate.setTime(tripItem2.timePeriod.endDate.getTime());
					}
					
					hotelStartDate.minutes++;
				}
				else
				{
					if (_visitsRow.length > 0)
					{
						// hotel int begin van alle visits zetten
						hotelStartDate.setTime(_timelineController.timelineEndDate);
						
						for each(var tripScheduleEntry2: TripScheduleEntry in _visitsRow)
						{
							var tripItem3: TripItem = tripScheduleEntry2.tripItem;
							if (tripItem3.timePeriod.startDate.getTime() < hotelStartDate.getTime())
								hotelStartDate.setTime(tripItem3.timePeriod.startDate.getTime());
						}
					}
				}
				
				var newStartDate: Date = new Date(hotelStartDate);
				var newEndDate: Date = new Date(hotelStartDate.getTime() + tripItem.timePeriod.getDuration());
				
				_timelineController.updateTripItemStartDate(tripItem, newStartDate);
				_timelineController.updateTripItemEndDate(tripItem, newEndDate);
				
				_hotelsRow.addItem(new TripScheduleEntry(tripItem));
			}
			
			private function timelineController_tripItemRemoved(event: TimelineControllerEvent): void
			{
				var tripScheduleEntry: TripScheduleEntry;
				
				for each (tripScheduleEntry in _visitsRow)
				{
					if (tripScheduleEntry.tripItem == event.tripItem)
					{
						_visitsRow.removeItemAt( _visitsRow.getItemIndex(tripScheduleEntry) );
						this.updateTimeline();
						return;
					}
				}
				
				for each (tripScheduleEntry in _hotelsRow)
				{
					if (tripScheduleEntry.tripItem == event.tripItem)
					{
						_hotelsRow.removeItemAt( _hotelsRow.getItemIndex(tripScheduleEntry) );
						this.updateTimeline();
						return;
					}
				}
				
				
				
			}
			
			private function timelineController_tripItemsCleared(event: TimelineControllerEvent): void
			{
				this._hotelsRow.removeAll();
				this._visitsRow.removeAll();
				
				this.updateTimeline();
			}
			
			private function basketController_tripItemUpdated(event: BasketControllerEvent): void
			{
				this.updateTimeline();
			}
			
			//handler bij het aanklikken van een IScheduleEntry
			private function scheduleViewer_selectScheduleEntry(event: EntryEvent): void
			{
				var tripItem: TripItem = (event.scheduleEntry as TripScheduleEntry).tripItem;
				
				//Event doorgeven als een TimelineEvent:
				dispatchEvent( new TimelineEvent("selectTripItem", tripItem) );
			}
			
			private function onZoom( value : Number ) : void
			{
				zoom = value;
			}
			
			private function onScrollTimeline( position : Number ) : void
			{
				scheduleViewer.xPosition = position;
			}
			
			private function onScrollScheduleViewer( event : ScrollEvent ) : void
			{
				if( event.direction == ScrollEventDirection.HORIZONTAL )
				{
					timelineFlexlib.xPosition = event.position;
				}
			}
			
			
			private function gotoNow() : void
			{
				var time : Date = new Date();
				scheduleViewer.moveToTime( time.getTime() - startDate.getTime() );
			}
			
			public function updateTimeline(): void
			{
				this.scheduleViewer.update();
			}
			
			public function selectTripItem(tripItem: TripItem): void
			{
				var tripScheduleEntryRenderers: Dictionary = this.scheduleViewer.schedule.entryViewer.visibleRenderers;
				
				for each(var tripScheduleEntryRenderer: TripScheduleEntryRenderer in tripScheduleEntryRenderers)
				{
					var timelineTripItem: TripItem = tripScheduleEntryRenderer.tripItem;
					if (tripItem == timelineTripItem)
					{
						tripScheduleEntryRenderer.selected = true;
					}
					else
					{
						tripScheduleEntryRenderer.selected = false;
					}
				}
				
			}
			
			


		]]>
	</mx:Script>
	
	

	<mx:HBox>
		<mx:List 
			id="rowsList" width="70" height="{ scheduleViewerHeight }" 
			dataProvider="{ rowDataProvider }" 
			rowHeight="{ scheduleViewer.rowHeight }" 
			verticalScrollPolicy="off" verticalAlign="middle"
			backgroundImage="icons/timeline_bg.png"
			backgroundAlpha="0.5"
			selectable="false"
			/>
			
		<flexlib:ScheduleViewer 
			id="scheduleViewer" 
			rowHeight="{timebarHeight}"
			width="{ scheduleViewerWidth }" height="{ scheduleViewerHeight }" borderStyle="none"
			dataProvider="{ dataProvider }"    
			startDate="{ startDate }" endDate="{ endDate }" 
			zoom="{ zoom }" 
			horizontalScrollPolicy="off" pixelScrollEnabled="true" 
			entryRenderer="tripvisUI.flexlibextention.TripScheduleEntryRenderer"  
			entryLayout="flexlib.scheduling.scheduleClasses.layout.SimpleLayout" 
			horizontalLinesViewer="flexlib.scheduling.samples.AlternatingHorizontalLinesViewer" 
			verticalLinesViewer="flexlib.scheduling.samples.SolidVerticalLinesViewer"  
			pixelScroll="onScrollScheduleViewer( event );" 
			backgroundImage="icons/timeline_bg.png"
			backgroundAlpha="0.5"
			selectScheduleEntry="scheduleViewer_selectScheduleEntry(event)"
			/>	
	</mx:HBox>
	
	<mx:HBox>
		<mx:Box paddingTop="24" paddingLeft="3">
			<mx:Button label="Nu" width="{rowsList.width - 6}" click="gotoNow();" visible="false"/>
		</mx:Box>
		

			
		<flexlib:Timeline 
			id="timelineFlexlib" 
			width="{ scheduleViewerWidth }" borderStyle="none"  
			startDate="{ startDate }" endDate="{ endDate }" 
			zoom="{ zoom }" 
			scroll="onScrollTimeline( event.position );" 
			horizontalScrollPolicy="on"
			/>
	</mx:HBox>
	
	<mx:HBox width="{ scheduleViewerWidth + rowsList.width }" paddingTop="-4">
		<mx:Label text="{LanguageDirector.instance.language.timelineZoom}:"/>
		<mx:HSlider 
			id="zoomSlider" 
			minimum="100" maximum="1000" value="{ zoom }" 
			snapInterval="1" liveDragging="true" 
			change="onZoom( zoomSlider.value );"
			showDataTip="false"
			width="100%"/>	
	</mx:HBox>
	
	

</mx:Box>